clear all
set more off

set obs 1000

forval i=1/3 {
	*gen x`i'=rnormal()
	gen x`i'=6*(runiform()-0.5)
}

egen ylin=rowtotal(x1-x3)

gen y=runiform()<invlogit(ylin)

logit y x*
est store three
logit y x1 x2
est store two
logit y x1
est store one

est table three two one
est table three two one, eform

est restore three
quietly margins, at(x1=(-5(0.2)5) x2=0 x3=0)
marginsplot, ylabel(0(0.2)1) noci title("x2=0, x3=0") name(allx)

est restore two
quietly margins, at(x1=(-5(0.2)5) x2=0)
marginsplot, ylabel(0(0.2)1) noci title("x2=0, no x3") name(centered)
quietly margins, at(x1=(-5(0.2)5) x2=-3)
marginsplot, ylabel(0(0.2)1) noci title("x2=-3, no x3") name(lower)
quietly margins, at(x1=(-5(0.2)5) x2=3)
marginsplot, ylabel(0(0.2)1) noci title("x2=3, no x3") name(upper)

*graph combine lower centered upper, row(1)

est restore one
quietly margins, at(x1=(-5(0.2)5))
marginsplot, ylabel(0(0.2)1) noci title("No x2, no x3") name(dropx2)

graph combine allx lower centered upper dropx2, holes(1 3 7 9) colfirst