log using "logit dropped var bias.log"
postfile cbias rep vars b se z using coefbias.dta, replace
postfile mbias rep vars b se z using margbias.dta, replace

quietly forvalues rep=1/5000 {
	clear
	set obs 200
	forvalues i=1/2 {
		generate x`i' = runiform(-3,3) // x's independent and balanced
		}
	egen ylo = rowtotal(x*)
	generate ypr = invlogit(ylo)
	generate y = runiform() < ypr
	logit y x*
	post cbias (`rep') (2) (_b[x1]) (_se[x1]) (_b[x1]/_se[x1])
	margins, dydx(x1) post
	post mbias (`rep') (2) (_b[x1]) (_se[x1]) (_b[x1]/_se[x1])
	logit y x1
	post cbias (`rep') (1) (_b[x1]) (_se[x1]) (_b[x1]/_se[x1])
	margins, dydx(x1) post
	post mbias (`rep') (1) (_b[x1]) (_se[x1]) (_b[x1]/_se[x1])
}
postclose cbias
postclose mbias

use coefbias.dta, clear
*bysort vars:  summarize
reshape wide b se z, i(rep) j(vars)
gen db = b2-b1
gen dse = se2-se1
gen dz = z2-z1
summarize
ttest db==0
ttest dse==0
ttest dz==0

use margbias.dta, clear
*bysort vars:  summarize
reshape wide b se z, i(rep) j(vars)
gen db = b2-b1
gen dse = se2-se1
gen dz = z2-z1
summarize
ttest db==0
ttest dse==0
ttest dz==0

log close