/*************************************

ex2.do

written 10/2007 by Russell Dimond

Example from
http://ssc.wisc.edu/sscc/pubs/4-26.htm

see also mataclass.do and ex1.do

**************************************/

clear
log using ex2.log,replace
mata
mata clear

/* Example: Ranking Teams */

str=uniform(1,50)

teams=1::50
season=teams
for(i=1;i<10;i++)
{
	season=season\teams
}
season=season,jumble(season)
same=(season[.,1]:==season[.,2])

while (max(same)==1)
{
	for(i=1; i<=rows(season); i++)
	{
		if (same[i])
		{
			swap=trunc(uniform(1,1)*rows(season))+1
			temp=season[swap,2]
			season[swap,2]=season[i,2]
			season[i,2]=temp
		}
	}
	same=(season[.,1]:==season[.,2])
}

winner=J(rows(season),1,.)
for(i=1; i<=rows(season); i++)
{
	winner[i]=uniform(1,1):<invlogit(str[season[i,1]]-str[season[i,2]])
}

function llf(todo,strhat,season,winner,llf,g,H)
{
	llf=J(rows(season),1,.)
	for(i=1;i<=rows(season);i++)
	{
		if (winner[i]) llf[i]=log(invlogit(strhat[season[i,1]]-strhat[season[i,2]]))
		else llf[i]=log(invlogit(strhat[season[i,2]]-strhat[season[i,1]]))
	}
}

s=optimize_init()
optimize_init_evaluator(s, &llf())
optimize_init_evaluatortype(s,"v0")
strhat0=J(1,rows(teams),.5)
optimize_init_params(s,strhat0)
optimize_init_argument(s,1,season)
optimize_init_argument(s,2,winner)
end
timer on 1
mata
strhat1=optimize(s)
end
timer off 1
mata

season2=J(rows(season),2,.)
for(i=1;i<=rows(season);i++)
{
	if (winner[i]) season2[i,.]=season[i,.]
	else season2[i,.]=season[i,(2,1)]
}

function llf2(todo,strhat,season,llf,g,H)
{
	x=J(rows(season),1,.)
	for(i=1;i<=rows(season);i++)
	{
		x[i]=strhat[season[i,1]]-strhat[season[i,2]]
	}
	llf=log(invlogit(x))
}


s=optimize_init()
optimize_init_evaluator(s, &llf2())
optimize_init_evaluatortype(s,"v0")
strhat0=J(1,rows(teams),.5)
optimize_init_params(s,strhat0)
optimize_init_argument(s,1,season2)
end
timer on 2
mata
strhat2=optimize(s)
end
timer off 2
mata

C=e(1,rows(teams))
c=0

optimize_init_constraints(s,(C,c))

end
timer on 3
mata
strhat3=optimize(s)
end
timer off 3

timer list
log close